This post introduce two exemplar queries for interrogating the OpenCitations Corpus.

Silvio Peroni

[OpenCitations](http://opencitations.net) makes available a [SPARQL
endpoint](http://opencitations.net/sparql) for querying the data
included in the OpenCitations Corpus. While several queries are possible
according to the [model described in the
website](http://opencitations.net/model) (and, with more details, in the
[official metadata
document](https://dx.doi.org/10.6084/m9.figshare.3443876) of the
Corpus), we have received some requests by users of the service for
exemplar queries. We have chosen two of them, which are particularly
relevant with regard to the work that has been done in the past months
by the [Initiative for Open Citations](https://i4oc.org) -- that we have
already introduced in [another blog
post](https://opencitations.hypotheses.org/696).

**Query:** return all the papers (including their titles) citing the
article with DOI "10.1038/227680a0".

    PREFIX cito: <http://purl.org/spar/cito/>
    PREFIX dcterms: <http://purl.org/dc/terms/>
    PREFIX datacite: <http://purl.org/spar/datacite/>
    PREFIX literal: <http://www.essepuntato.it/2010/06/literalreification/>
    SELECT ?citing ?title WHERE {
      ?id a datacite:Identifier ;
        datacite:usesIdentifierScheme datacite:doi ;
        literal:hasLiteralValue "10.1038/227680a0" .
      ?br 
        datacite:hasIdentifier ?id ;
        ^cito:cites ?citing .
      ?citing dcterms:title ?title
    }

**Query:** return all the papers cited by the bibliographic resource
"br/4186" included in the OCC, including the text of bibliographic
references used in "br/4186" for making the citations and the titles of
the cited papers.

    PREFIX cito: <http://purl.org/spar/cito/>
    PREFIX dcterms: <http://purl.org/dc/terms/>
    PREFIX biro: <http://purl.org/spar/biro/>
    PREFIX frbr: <http://purl.org/vocab/frbr/core#>
    PREFIX c4o: <http://purl.org/spar/c4o/>
    SELECT ?cited ?cited_ref ?title WHERE {
      <https://w3id.org/oc/corpus/br/4186> cito:cites ?cited .
      OPTIONAL { 
        <https://w3id.org/oc/corpus/br/4186> frbr:part ?ref .
        ?ref biro:references ?cited ;
          c4o:hasContent ?cited_ref 
      }
      OPTIONAL { ?cited dcterms:title ?title }
    }


OpenCitations makes available a SPARQL endpoint for querying the data included in the OpenCitations Corpus. While several queries are possible according to the model described in the website (and, with more details, in the official metadata document of the Corpus), we have received some requests by users of the service for exemplar queries.

Messaggi di Rogue Scholar

Querying the OpenCitations Corpus